Anillo 3 - Original
An interactive fiction by Mel Hython (2009) - the Inform 7 source text
Contents
Previous
Next
Complete text
Lava is a habitacionDecorada in Castillo.
Lava can be congelada. Lava is not congelada.
The printed name of Lava is "[if Lava is not congelada]Un tunel surcado por un río de lava[otherwise]Un túnel oscuro[end if]".
The description of Lava is "[if Lava is not congelada]Un vibrante río de lava cruza este lugar de norte a sur. Al otro lado del río, al oeste puede divisarse un túnel. Probablemente ese sea tu destino.[otherwise]El lugar ha quedado temporalmente transformado en roca endurecida y oscura. Al otro lado, al oeste te espera un prometedor túnel de salida.[end if]".
The decoracion of Lava is Table of DecoLava.
Table of DecoLava
| topic | descripcion | printedName |
| "lava" or "rio" or "roca" | "[if Lava is not congelada]La roca hirviente siempre es una visión reconfortante para un dragón. Las leyendas dragón hablan de héroes míticos de vuestro pueblo que surcaban estas aguas de fuego, que vivían en ellas o que nacieron de ellas. Pero lo que vale para los héroes míticos no se aplica a los mortales, ni siquiera a los dragones. Si intentas cruzar este río de lava morirás sin remedio.[otherwise]Ver la lava transformada en roca es un alivio pues permite que sigas avanzando hacia tu destino, pero aún así resulta una visión decepcionante, nostálgica. Es como el mundo que desde el final de la Edad Ígnea se endurece y vuelve oscuro.[end if]" | "la lava" |
[Salidas]
Lugar Oo Drack is west of Lava.
Cueva4 is north of Lava.
[¡¡La lava no se puede cruzar!!]
Instead of going west from Lava when Lava is not congelada:
say "Oh... oh...";
bnw;
say "¡Maldita sea! Con la emoción olvidaste por completo que no puedes volar y que tu portador no puede soportar la lava hirviente.";
bnw;
muerte en la lava.
To muerte en la lava:
say "Sientes su terrible suplicio mientras se incinera con un poco de culpabilidad.";
bnw;
say "Oh...oh...";
bnw;
say "Estás sintiendo demasiado calor. Demasiado calor... ¡esto es mucho peor que una olla de hirviente cera!";
bnw;
say "Tu ojo esmeraldino se quiebra finalmente y tu alma de dragón se escapa, probablemente condenada al helado infierno de los dragones por haber finalizado su vida con semejante estupidez.";
end the game saying "FIN";
Instead of jumping when location is Lava:
if Lava is congelada:
say "Saltas... para caer a la mitad del río de lava... endurecido... por suerte.";
try going west;
otherwise:
try entering west.
After going west from Lava when Lava is congelada:
Oo Drack ataca in five turns from now;
continue the action.
Instead of going from Lava when in darkness:
say "¡Ouch!";
bnw;
say "Intentando ir en esa dirección tu portador choca violentamente contra una pared.";
bnw;
say "Esto es demasiado grande, necesitarías luz.".
Instead of going east from Lava when in darkness:
if a random chance of 2 in 3 succeeds:
say "Intentando salir de este lugar tu portador choca violentamente contra algo.";
bnw;
say "Esto es demasiado grande, necesitarías luz.";
otherwise:
continue the action.